I need to set CurrentRecord in a DAO recordset...

[Relentless]

I'm using the FindFirst method to find the matching record in a field but it will only update the first record. What am I doing wrong?

With rstLoggedIn
    .MoveFirst
    Do Until .EOF - 1
    .FindFirst !employeeid = EmpID
    .MoveNext
    If .NoMatch Then
        MsgBox "No records found with " & _
        EmpID & "."
        Exit Do
    End If
    Loop
    .Edit
    !EquipSetF1 = cboEquipSetF1.Text
    !EquipSetF2 = cboEquipSetF2.Text
    !LoggedIn = True
    .Update
End With

Thanks
Rel

[George1111]

You are continually saying FINDFIRST

ie, always find the first occurance of the match in your loop

If you want subsequent occurances of the same match you will need to say

FINDNEXT to find those records AFTER the first found record

[Relentless]

I am looking for the first occurance of the string EmpID in the EmployeeID field. There is only one occurance of a particular EmpID in this recordset. The NoMatch remains false, meaning the record was found. However, when I try to Edit the found record, it only changes the first record. I tried FindNext with the same results.

Thanks
Rel

[George1111]

Take out your .MOVENEXT statement

Also .MOVEFIRST is not required

With rstLoggedIn
     Do Until .EOF - 1
    .FindFirst !employeeid = EmpID
    If .NoMatch Then
        MsgBox "No records found with " & _
        EmpID & "."
        Exit Do
    End If
    Loop
    .Edit
    !EquipSetF1 = cboEquipSetF1.Text
    !EquipSetF2 = cboEquipSetF2.Text
    !LoggedIn = True
    .Update
End With

[JeffB]

Remove this loop, if there is no match found, it will loop forever, you only need ONE .findfirst call, then the recordset will try to find the first occurance, browsing all the records, you don't need to try another findfirst on this recordset, so no need for a loop. I guess this should work correctly:

With rstLoggedIn

    .FindFirst !employeeid = EmpID

    If .NoMatch Then
        MsgBox "No records found with " & _
        EmpID & "."
    Else
       .Edit
        !EquipSetF1 = cboEquipSetF1.Text
        !EquipSetF2 = cboEquipSetF2.Text
        !LoggedIn = True
        .Update
    End If

End With

JeffB

[Relentless]

OK, Still no luck. It will only edit and update the first record. EmpID is correct and it DOES exist in the table... In fact I read the EmployeeID field to populate a combobox, Which I use to select EmpID. When I select the second records EmployeeID and try to FindFirst, NoMatch goes true.

Private Sub cmdLogIn_Click()

Set rstLoggedIn = dbPageMe.OpenRecordset("LoggedIn", dbOpenDynaset)

If cboEquipSetF1.Text = "" And cboEquipSetF2.Text = "" Then
    MsgBox "Please Select Equipment Set"
    Exit Sub
End If

With rstLoggedIn

    .FindFirst !EmployeeID = EmpID

    If .NoMatch Then
        MsgBox "No records found with " & EmpID & "."
    Else
        .Edit
        !EquipSetF1 = cboEquipSetF1.Text
        !EquipSetF2 = cboEquipSetF2.Text
        !LoggedIn = True
        .Update
    End If

End With

rstLoggedIn.Close

Me.Hide

End Sub

Thanks
Rel

[JeffB]

The .FindFirst() method ask for a string parameters, you are not using it correctly, what you need to do is something like that:

.FindFirst "EmployeeID = " & EmpID

It's like using an SQL where clause.

JeffB

[Relentless]

Yes you are correct sir. this did it

With rstLoggedIn
    .FindFirst "EmployeeID = '" & EmpID & "'"
    .Edit
    !EquipSetF1 = cboEquipSetF1.Text
    !EquipSetF2 = cboEquipSetF2.Text
    !LoggedIn = True
    .Update
End With

Many thanks... again, Jeff
Relentless